source: default/trunk/de.ugoe.cs.swe.bnftools.ebnf.samples/trunk/tplan/tplan-v1.2.1.bnf @ 5

grammar tplan/bnf;

// BNF grammar for TSS & TP language (TPLan) 
// Version: 2.6 
// Date: 08.10.2007 
// Author: ETSI CTI 
// TSS header 
tss_header ::= KWD_tss DELIM ext_tss_id [ tss_title ] [ tss_version ] [ tss_date ] [ tss_author ] [ { user_tss_header } ] tss_body;
tss_title ::= KWD_title DELIM qstring;
tss_version ::= KWD_version DELIM numeric [ { DOT numeric } ];
tss_date ::= KWD_date DELIM '[0-9][0-9]' DOT '[0-9][0-9]' DOT '[0-9][0-9][0-9][0-9]' | '[0-9][0-9]' F_SLASH '[0-9][0-9]' F_SLASH '[0-9][0-9][0-9][0-9]' | '[0-9][0-9]' DASH '[0-9][0-9]' DASH '[0-9][0-9][0-9][0-9]';
tss_author ::= KWD_author DELIM qstring;
user_tss_header ::= { header_id | TSS_header_KWDS } DELIM ( user_header_list | qstring );
user_header_list ::= extended_id [ { SEPARATOR extended_id } ];

// TSS body 
tss_body ::= [ { xrefs } ] [ { definitions } ] { group | tp };

// References and definitions 
xrefs ::= KWD_xref ext_xref_id L_BRACE extended_id [ { SEPARATOR extended_id } ] R_BRACE;
definitions ::= KWD_def ( define_word | define_header | define_event | define_entity | define_unit | define_value | define_condition | define_context ) [ qstring ] | includes;
includes ::= "#include" qstring;
define_word ::= KWD_word word_id [ { SEPARATOR word_id } ];
define_header ::= KWD_header header_id [ { SEPARATOR header_id } ];
define_event ::= KWD_event event_id [ field_list ] [ { SEPARATOR event_id [ field_list ] } ];
field_list ::= L_BRACE field_id | value_id [ { SEPARATOR field_id | value_id } ] R_BRACE;

// STATIC SEMANTICS 1: field_id shall be unique in the field list 
define_entity ::= KWD_entity entity_id [ { SEPARATOR entity_id } ];
define_unit ::= KWD_unit unit_id [ { SEPARATOR unit_id } ];
define_value ::= KWD_value value_id [ field_list ] [ { SEPARATOR value_id [ field_list ] } ];
define_condition ::= KWD_condition condition_id [ { SEPARATOR condition_id } ];
define_context ::= KWD_context L_BRACE { context } R_BRACE;
context ::= [ L_BRACKET ] context_id [ R_BRACKET ];

// STATIC SEMANTICS 2: If used, each and every L_BRACKET shall be paired with a corresponding 
// Grouping 
group ::= group_header [ group_objective ] [ { group | tp } ] [ group_num ] [ qstring ]
group_header ::= KWD_group [ group_num ] [ qstring ];
group_objective ::= KWD_objective DELIM [ qstring ];
tp ::= ( tp_header tp_body ) | includes;

// TP Header 
tp_header ::= tp_identifier [ summary ] [ req_ref ] [ role ] [ config_ref ] [ tc_or_td_ref ] [ { user_tp_header } ];
tp_identifier ::= KWD_TP KWD_id DELIM ext_TP_id;
summary ::= KWD_tp_summary DELIM [ qstring ];
req_ref ::= KWD_req KWD_ref DELIM [ cat_ref_list ];
role ::= KWD_role DELIM [ role_ref_list ];
config_ref ::= KWD_config DELIM [ ext_CF_id ];
tc_or_td_ref ::= tc_ref | td_ref;
tc_ref ::= KWD_TC KWD_ref DELIM ext_TC_id;
td_ref ::= KWD_TD KWD_ref DELIM ext_TD_id;
cat_ref_list ::= ext_RQ_id [ { SEPARATOR ext_RQ_id } ];
role_ref_list ::= role_id [ { SEPARATOR role_id } ];
user_tp_header ::= { TPLan_Hid | TP_header_KWDS } DELIM ( user_header_list | qstring );

// TP body 
tp_body ::= [ preconditions ] KWD_ensure KWD_that begin_tp { [ stimuli ] responses } end_tp;
preconditions ::= KWD_precondition begin_conditions [ precondition [ { KWD_logical precondition } ] ] end_conditions;
precondition ::= [ test_object ] mixed_text;
stimuli ::= KWD_stimulus begin_stimuli [ stimulus [ { KWD_logical stimulus } ] ] end_stimuli;
stimulus ::= [ test_object ] mixed_text;
responses ::= KWD_response begin_responses [ response [ { KWD_logical response } ] ] end_responses;
response ::= [ test_object ] mixed_text;
TPLan_word ::= predefined_words | num_id | TPLan_id;
test_object ::= TPLan_Eid | KWD_IUT | KWD_TESTER;
mixed_text ::= TPLan_word | qstring | ( mixed_text mixed_text ) | ( L_PAREN mixed_text R_PAREN );

// TPLan identifiers 
// STATIC SEMANTICS 2: no identifier of any kind shall be the same as any   
// other predefined or user-defined TPLan keyword or identifier 
// TSS and TP related identifiers 
ext_tss_id ::= extended_id;
ext_xref_id ::= extended_id;
ext_RQ_id ::= extended_id;
ext_CF_id ::= extended_id;
ext_TC_id ::= extended_id;
ext_TD_id ::= extended_id;
ext_TP_id ::= extended_id;
role_id ::= extended_id;

// Header identifiers 
header_id ::= extended_id;
TPLan_Hid ::= extended_id;

// Test entity identifiers 
entity_id ::= extended_id;
TPLan_Eid ::= extended_id;

// Event (Message) and field identifiers) 
field_id ::= extended_id;
event_id ::= extended_id;

// Unit identifiers 
value_id ::= extended_id;

// Value identifiers 
unit_id ::= extended_id;

// Word identifiers 
word_id ::= extended_id;
TPLan_id ::= extended_id;

// Condition identifiers 
condition_id ::= extended_id;
extended_id ::= '[a-zA-Z0-9|._&%$*@%?></\#!-]+';
context_id ::= [ "~" ] extended_id

// Numbering 
group_num ::= numeric [ { DOT numeric } ];
numeric ::= '[0-9]+';
num_id ::= '[0-9.eE]+';

// STATIC SEMANTICS 3: Table 1 of this present document shows alternative forms of  
// case sensitivity for the TPLan keywords.  
// For simplicity the keywords shown in this BNF correspond to the  
// left-hand column of Table 1. The alternatives in column 2 are assumed. 
// TSS header keywords 
TSS_header_KWDS ::= KWD_author | KWD_date | KWD_title | KWD_tss | KWD_version;
KWD_author ::= "author";
KWD_date ::= "date";
KWD_title ::= "title";
KWD_tss ::= "TSS";
KWD_version ::= "version";

// Reference and definition keywords 
KWD_xref ::= "xref";
KWD_condition ::= "condition";
KWD_context ::= "context";
KWD_def ::= "def";
KWD_entity ::= "entity";
KWD_event ::= "event";
KWD_header ::= "header";
KWD_value ::= "value";
KWD_unit ::= "unit";
KWD_word ::= "word";

// Group keywords 
KWD_end ::= "end";
KWD_group ::= "group";
KWD_objective ::= "objective";

//TP header keywords 
TP_header_KWDS ::= KWD_config | KWD_id | KWD_ref | KWD_role | KWD_req | KWD_tp_summary | KWD_TC | KWD_TD | KWD_TP;
KWD_config ::= "config";
KWD_id ::= "id";
KWD_ref ::= "ref";
KWD_role ::= "role";
KWD_req ::= "RQ";
KWD_tp_summary ::= "summary";
KWD_TC ::= "TC";
KWD_TD ::= "TD";
KWD_TP ::= "TP";

//TP body (structure) keywords 
KWD_ensure ::= "ensure";
KWD_that ::= "that";
KWD_response ::= "then";
KWD_stimulus ::= "when";
KWD_precondition ::= "with";
KWD_logical ::= "and" | "or" | "and not" | "or not";

//Test entity keywords 
KWD_IUT ::= "IUT";
KWD_TESTER ::= "TESTER";

//Predefined words 
predefined_words ::=

// glue words 
"a" | "an" | "as" | "in" | "is" | "no" | "of" | "the"

// logical words 
| "and" | "not" | "or"

// stimulus and response words 
| "receives" | "sends"

// data-related words 
| "containing" | "indicating"

//direction words 
| "from" | "to"

// time- or order-related words 
| "after" | "before" | "unorderd" | "within";

// Begin/End symbols 
begin_stimuli ::= L_BRACE;
end_stimuli ::= R_BRACE;
begin_conditions ::= L_BRACE;
end_conditions ::= R_BRACE;
begin_responses ::= L_BRACE;
end_responses ::= R_BRACE;
begin_tp ::= L_BRACE;
end_tp ::= R_BRACE;

// Delimiters, separators etc. 
DASH ::= "-";
DELIM ::= ":";
DOT ::= ".";
F_SLASH ::= "/";
L_BRACE ::= "{";
R_BRACE ::= "}";
L_BRACKET ::= "[";
R_BRACKET ::= "]";
L_PAREN ::= "(";
R_PAREN ::= ")";
LT ::= "<";
RT ::= ">";
SEPARATOR ::= ",";
U_SCORE ::= "_";
qstring ::= //"'" *("'") "'"; // meaning unclear